
***********************************************************
*** Creature acting on another Creature: 32+
*** note: does not include breading scripts which
*** are kept in creature breeding.cos
***********************************************************



******* Creature - intro quiescent - Special Overide[0]
scrp 4 0 0 32
	loop
		doif rand 0 1 eq 0
			pose 57
			wait rand 20 40
		else
			pose 59
			wait rand 1 10
			pose 60
			wait rand 1 10
		endi

*stim yourself with quiescent
		stim writ targ 12 1
	ever
endm


************* Creature - mate - Special Overide[1]
* scrp 4 0 0 33 : kept in creatureBreeding.cos

************ Creature - mate (copy of 33) - Special Overide[2]
* scrp 4 0 0 34 : kept in creature breeding .cos


****************Creature - HIT - Special Overide[13]
scrp 4 0 0 45
	appr
	inst
	doif _it_ = null
		wait 10
		stop
	endi

	touc
	inst
	doif _it_ = null
		wait 10
		stop
	endi

	doif byit eq 0
* disappointment
		stim writ targ 0 1
		wait 10
		stop
	endi
	targ _it_
*if it is dead then stop
	doif dead ne 0
		targ ownr
* disappointment
		stim writ targ 0 1
		wait 10
		stop
	endi
* if dreaming stop it, if not dreaming wake up:
* set IT genus in va11
	setv va11 gnus
	doif drea eq 1
		drea 0
	else
		aslp 0
	endi
* don't hold hands anymore, IT:
	nohh
	targ ownr
* set MY genus in va10
	setv va10 gnus

	anim [111 112 113 114 111]
	doif gnus ne 2
		snde "spnk"
	else
* grendels punch
		snde "punc"
	endi
*stim yourself with AGGRESSION
	stim writ ownr 44 1
*tell & stim _IT_ ive been hit
	mesg writ _it_ 3


	inst
* strength of hit depends on life-stage:
	setv va00 0.0
* Baby:  0.0
	doif cage eq 0
		setv va00 0
* Child:  0.25
	elif cage eq 1
		setv va00 0.25
* Adolescent: 0.5
	elif cage eq 2
		setv va00 0.5
*Youth: 0.75
	elif cage eq 3
		setv va00 0.75
*Adult: 1.0
	elif cage eq 4
		setv va00 1.0
* Old: 0.5
	elif cage eq 5
		setv va00 0.5
*Senile: 0.0
	elif cage eq 6
		setv va00 0.0
	endi

* add one to stim coz that's what it was before:
	addv va00 1.0
* modify based on gnus: against same species is .5 strength:
	doif va10 = va11
		mulv va00 0.25
	endi
* (gotta check va00 unfort coz 0.0 means "no training"):
	doif va00 ne 0.0
* creature slap stim:
		stim writ _it_ 4 va00
	endi
endm