* Script  4 Picked up
scrp 2 19 1 4
	tick 0
	doif ov00 eq 0
		base 0
		anim [210123R]
	endi
	doif ov00 eq 1
		base 4
		anim [210123R]
	endi
	stim writ from 0 10 100 0 18 100 0 0 0 0 0 0
endm

* Script  5 Dropped
scrp 2 19 1 5
	tick 5
endm

* Script  9 TIMER
scrp 2 19 1 9
	gsub decf
	doif ov02 eq 0
		doif tmod eq 3
			gsub wake
		endi
		stop
	endi
	doif ov02 eq 1
		tick 5
		gsub chkr
		doif ov03 eq 0
			gsub flya
			doif ov09 le 0
				addv ov05 1
				doif ov05 ge 10
					setv ov05 0
					gsub sele
				endi
			endi
			stop
		endi
		doif ov03 eq 1
			gsub relf
			gsub face
			gsub flyd
			gsub absv
			doif var0 le 10
				doif var1 le 10
					gsub eat_
				endi
			endi
			doif var9 eq 0
				gsub coll
			endi
			addv ov05 1
			doif ov05 ge 30
				setv ov03 0
				setv ov05 0
			endi
			stop
		endi
		stop
	endi
	doif ov02 eq 2
		gsub relr
		gsub face
		gsub flyd
		gsub absv
		doif var0 le 20
			doif var1 le 20
				gsub roos
			endi
		endi
		stop
	endi
	subr decf
		doif ov09 gt 0
			subv ov09 1
		endi
	retn
	subr wake
		setv attr 195
		slim
		setv grav 1
		rndv ov00 0 1
		rndv ov01 0 1
		doif ov00 eq 0
			base 8
			anim [0123]
		else
			base 12
			anim [0123]
		endi
		setv ov02 1
		tick 15
	retn
	subr chkr
		doif tmod eq 0
			setv ov02 2
			setv attr 128
			slim
		endi
	retn
	subr sele
		inst
		star 2 25 0
		doif targ ne 0
			setv var0 posx
			setv var1 posy
			targ ownr
			setv ov03 1
			setv ov07 var0
			setv ov08 var1
		endi
		slow
	retn
	subr relf
		setv var0 ov07
		setv var1 ov08
		subv var0 posx
		subv var1 posy
		gsub wrap
	retn
	subr face
		doif var0 lt 0
			setv ov00 0
		else
			setv ov00 1
		endi
		doif var1 lt 0
			setv ov01 0
		else
			setv ov01 1
		endi
	retn
	subr flya
		gsub chdi
		gsub flyd
		gsub coll
	retn
	subr chdi
		rndv var0 0 99
		doif var0 eq 0
			rndv ov00 0 1
			rndv ov01 0 1
		endi
	retn
	subr flyd
		doif ov00 eq 0
			base 0
			anim [210123]
			rndv velx -7 -9
		endi
		doif ov00 eq 1
			base 4
			anim [210123]
			rndv velx 7 9
		endi
		doif rtyp eq 2
			setv vely -50
		else
			doif ov01 eq 0
				rndv vely -15 -10
			else
				rndv vely -5 0
			endi
		endi
		snde flap
	retn
	subr coll
		slim
		doif obst ov00 le 0
			addv ov04 1
			doif ov04 ge 10
				setv ov04 0
				doif ov00 eq 0
					setv ov00 1
				else
					setv ov00 0
				endi
			endi
		else
			setv ov04 0
		endi
		setv var9 ov01
		addv var9 2
		doif obst var9 le 0
			doif ov01 eq 0
				setv vely 0
			else
				setv vely -15
			endi
		endi
	retn
	subr absv
		doif var0 lt 0
			negv var0
		endi
		doif var1 lt 0
			negv var1
		endi
	retn
	subr eat_
		setv var9 0
		etch 2 25 0
		doif relx ge -15
			doif relx le 15
				doif rely ge -15
					doif rely le 15
						setv var9 1
					endi
				endi
			endi
		endi
	next
	targ ownr
	doif var9 eq 1
		setv velx 0
		setv vely 0
		setv grav 0
		gsub han2
		base 26
		anim [0123]
		over
		snde eat1
		anim [210]
		over
		setv ov03 0
		setv var0 0
		etch 2 25 0
		doif var0 eq 0
			doif relx ge -20
				doif relx le 20
					doif rely ge -20
						doif rely le 20
							kill targ
							setv var0 1
						endi
					endi
				endi
			endi
		endi
	next
	doif var0 eq 1
		addv ov09 1000
	endi
endi
retn
subr relr
	setv var0 ov10
	setv var1 ov11
	subv var0 posl
	subv var1 post
	gsub wrap
retn
subr roos
	setv velx 0
	setv vely 0
	setv grav 0
	setv attr 0
	gsub han1
	setv ov02 0
	stop
retn
subr han1
	doif ov00 eq 0
		base 16
		pose 0
		mvby 5 3
		pose 1
		mvby 2 6
		pose 2
		mvby 3 13
		pose 3
		mvby -5 2
		pose 4
	endi
	doif ov00 eq 1
		base 21
		pose 0
		mvby -5 3
		pose 1
		mvby -2 6
		pose 2
		mvby -3 13
		pose 3
		mvby 5 2
		pose 4
	endi
retn
subr han2
	doif ov00 eq 0
		base 16
		anim [01234]
	endi
	doif ov00 eq 1
		base 21
		anim [01234]
	endi
retn
subr wrap
	doif var0 gt 4176
		subv var0 8352
	endi
	doif var0 lt -4176
		addv var0 8352
	endi
retn
endm

